Implement the ability to devour only uncached derivations of a flake

devour/flake.nix

@@ -0,0 +1,52 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    systems.url = "github:nix-systems/default";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    flake = { };
+  };
+  outputs = inputs@{ flake-parts, systems, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = import systems;
+      perSystem = { self', pkgs, lib, system, ... }: {
+        packages.default =
+          let
+            # Given a flake output key, how to get the buildable derivation for
+            # any of its attr values?
+            flakeSchema = {
+              perSystem = {
+                lookupFlake = k: lib.attrByPath [ k system ] { };
+                getDrv = {
+                  packages = _: x: [ x ];
+                  checks = _: x: [ x ];
+                  devShells = _: x: [ x ];
+                  apps = _: app: [ app.program ];
+                  legacyPackages = k: v:
+                    if k == "homeConfigurations"
+                    then
+                      lib.mapAttrsToList (_: cfg: cfg.activationPackage) v
+                    else [ ];
+                };
+              };
+              flake = {
+                lookupFlake = k: lib.attrByPath [ k ] { };
+                getDrv = {
+                  nixosConfigurations = _: cfg:
+                    lib.optional pkgs.stdenv.isLinux cfg.config.system.build.toplevel;
+                  darwinConfigurations = _: cfg: 
+                    lib.optional pkgs.stdenv.isDarwin cfg.config.system.build.toplevel;
+                };
+              };
+            };
+            paths =
+              lib.flip lib.mapAttrsToList flakeSchema (lvl: lvlSchema:
+                lib.flip lib.mapAttrsToList lvlSchema.getDrv (kind: getDrv:
+                  lib.mapAttrsToList
+                    getDrv
+                    (lvlSchema.lookupFlake kind inputs.flake))
+              );
+          in
+          pkgs.writeText "devour-output" (lib.strings.concatLines (lib.lists.flatten paths));
+      };
+    };
+}

flake.nix

@@ -3,52 +3,25 @@
     nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
     systems.url = "github:nix-systems/default";
     flake-parts.url = "github:hercules-ci/flake-parts";
-    flake = { };
   };
   outputs = inputs@{ flake-parts, systems, ... }:
     flake-parts.lib.mkFlake { inherit inputs; } {
       systems = import systems;
       perSystem = { self', pkgs, lib, system, ... }: {
-        packages.default =
-          let
-            # Given a flake output key, how to get the buildable derivation for
-            # any of its attr values?
-            flakeSchema = {
-              perSystem = {
-                lookupFlake = k: lib.attrByPath [ k system ] { };
-                getDrv = {
-                  packages = _: x: [ x ];
-                  checks = _: x: [ x ];
-                  devShells = _: x: [ x ];
-                  apps = _: app: [ app.program ];
-                  legacyPackages = k: v:
-                    if k == "homeConfigurations"
-                    then
-                      lib.mapAttrsToList (_: cfg: cfg.activationPackage) v
-                    else [ ];
-                };
-              };
-              flake = {
-                lookupFlake = k: lib.attrByPath [ k ] { };
-                getDrv = {
-                  nixosConfigurations = _: cfg:
-                    lib.optional pkgs.stdenv.isLinux cfg.config.system.build.toplevel;
-                  darwinConfigurations = _: cfg: 
-                    lib.optional pkgs.stdenv.isDarwin cfg.config.system.build.toplevel;
-                };
-              };
-            };
-            paths =
-              lib.flip lib.mapAttrsToList flakeSchema (lvl: lvlSchema:
-                lib.flip lib.mapAttrsToList lvlSchema.getDrv (kind: getDrv:
-                  lib.mapAttrsToList
-                    getDrv
-                    (lvlSchema.lookupFlake kind inputs.flake))
-              );
-          in
-          pkgs.runCommand "devour-output" { inherit paths; } ''
-            echo -n $paths > $out
-          '';
+        packages = rec {
+          default = pkgs.symlinkJoin {
+            name = "devour-flake";
+            paths = [
+              devour-flake
+              devour-flake-uncached
+            ];
+          };
+
+          # Build all derivations in a flake (or download them from the cache)
+          devour-flake = pkgs.callPackage ./pkgs/devour-flake.nix { };
+          # Only build all uncached derivations in flake
+          devour-flake-uncached = pkgs.callPackage ./pkgs/devour-flake-uncached.nix { };
+        };
       };
     };
 }

pkgs/devour-flake-uncached.nix

@@ -0,0 +1,43 @@
+{ coreutils-full
+, findutils
+, jq
+, nix
+, nix-build-uncached
+, writeShellApplication
+}:
+
+writeShellApplication {
+  name = "devour-flake-uncached";
+  runtimeInputs = [
+    coreutils-full
+    findutils
+    jq
+    nix
+    nix-build-uncached
+  ];
+  text = ''
+    set -euo pipefail
+
+    FLAKE="$1"
+    shift 1 || true
+
+    outDir=$(mktemp -d devour-flake-uncached.XXXX)
+    cleanup() {
+      rm -rf "$outDir"
+    }
+    trap cleanup EXIT
+
+    nix derivation show \
+      ${../devour}#default \
+      "$@" \
+      -L \
+      --reference-lock-file ${../flake.lock} \
+      --override-input flake "$FLAKE" \
+      | jq -r 'to_entries[].value.inputDrvs | to_entries[].key' \
+      | (
+        cd "$outDir"
+        1>&2 xargs nix-build-uncached
+        find . -type l -exec readlink '{}' \;
+      )
+  '';
+}

default.nix → pkgs/devour-flake.nix

@@ -9,9 +9,10 @@ writeShellApplication {
     FLAKE="$1"
     shift 1 || true
 
-    nix build ${./.}#default \
+    nix build ${../devour}#default \
       "$@" \
       -L --no-link --print-out-paths \
+      --reference-lock-file ${../flake.lock} \
       --override-input flake "$FLAKE" \
       | xargs cat 
   '';