flake: add nixosModules

flake.nix

@@ -13,6 +13,7 @@
       imports = [
         inputs.parts.flakeModules.partitions
         ./modules/parts
+        ./modules/nixos
         ./hosts
         ./users
       ];

modules/nixos/default.nix

@@ -0,0 +1,10 @@
+{ lib, ... }:
+
+{
+  flake.nixosModules = lib.pipe ./. [
+    lib.filesystem.listFilesRecursive
+    (__filter (f: lib.hasSuffix "nix" f && !(lib.hasSuffix "default.nix" f)))
+    (map (f: lib.nameValuePair (lib.removeSuffix ".nix" (baseNameOf f)) (import f)))
+    __listToAttrs
+  ];
+}

modules/nixos/shpool.nix

@@ -0,0 +1,46 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.services.shpool;
+in
+{
+  options.services.shpool = {
+    enable = lib.mkEnableOption "shpool, a service that enables session persistence";
+    package = lib.mkPackageOption pkgs "shpool" { };
+  };
+
+  config = lib.mkIf cfg.enable {
+    systemd = {
+      services.shpool = {
+        description = "Shpool - Shell Session Pool";
+        requires = [ "shpool.socket" ];
+
+        serviceConfig = {
+          Type = "simple";
+          ExecStart = "${cfg.package}/bin/shpool daemon";
+          KillMode = "mixed";
+          TimeoutStopSec = "2s";
+          SendSIGHUP = "yes";
+        };
+
+        wantedBy = [ "default.target" ];
+      };
+
+      sockets.shpool = {
+        description = "Shpool Shell Session Pooler";
+
+        socketConfig = {
+          ListenStream = "%t/shpool/shpool.socket";
+          SocketMode = "0600";
+        };
+
+        wantedBy = [ "sockets.target" ];
+      };
+    };
+  };
+}