linux-show-player: init at 0.6.4

pkgs/by-name/li/linux-show-player/package.nix

@@ -0,0 +1,85 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+  qt5,
+  wrapGAppsHook3,
+  gobject-introspection,
+  libjack2,
+  ola,
+  nix-update-script,
+}:
+let
+  version = "0.6.4";
+in
+python3.pkgs.buildPythonApplication {
+  pname = "linux-show-player";
+  inherit version;
+  pyproject = true;
+
+  # 3.13 is unsupported for now
+  disabled = with python3.pkgs; pythonOlder "3.8" || pythonAtLeast "3.13";
+
+  src = fetchFromGitHub {
+    owner = "FrancescoCeruti";
+    repo = "linux-show-player";
+    tag = "v${version}";
+    hash = "sha256-QgsgG+SeHT9bZgSkpo5AKpm/YIifn7qRfe/C3paMS5o=";
+  };
+
+  nativeBuildInputs = [
+    qt5.wrapQtAppsHook
+    wrapGAppsHook3
+
+    gobject-introspection
+  ];
+
+  build-system = with python3.pkgs; [ poetry-core ];
+
+  dependencies = with python3.pkgs; [
+    appdirs
+    falcon
+    jack-client
+    mido
+    pygobject3
+    pyqt5
+    python-rtmidi
+    requests
+    sortedcontainers
+    humanize
+    pyalsa
+    pyliblo
+
+    # Undocumented dependencies. *sigh*
+    gst-python
+    ola # Using Python bindings
+  ];
+
+  buildInputs = [ libjack2 ];
+
+  pythonRemoveDeps = [
+    "pyqt5-qt5"
+    "pyliblo3"
+  ];
+
+  dontWrapQtApps = true;
+  dontWrapGApps = true;
+
+  makeWrapperArgs = [
+    ''--prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ libjack2 ]}"''
+    "\${qtWrapperArgs[@]}"
+    "\${gappsWrapperArgs[@]}"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Cue player designed for stage productions";
+    changelog = "https://github.com/FrancescoCeruti/linux-show-player/releases/tag/v${version}";
+    homepage = "https://linux-show-player.org/";
+    license = with lib.licenses; [ gpl3Only ];
+    maintainers = with lib.maintainers; [ pluiedev ];
+    platforms = lib.platforms.linux;
+    mainProgram = "linux-show-player";
+  };
+}

pkgs/development/python-modules/jack-client/default.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  cffi,
+  libjack2,
+  nix-update-script,
+}:
+let
+  version = "0.5.5";
+in
+buildPythonPackage {
+  pname = "jack-client";
+  inherit version;
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "spatialaudio";
+    repo = "jackclient-python";
+    tag = version;
+    hash = "sha256-SqDHFUlAtGbT/UJALykPvdP7+5KUlZkMpwYDjq+rU98=";
+  };
+
+  build-system = [ setuptools ];
+  dependencies = [ cffi ];
+
+  # Imports check dlopens libjack :V
+  postFixup = ''
+    export LD_LIBRARY_PATH=${lib.makeLibraryPath [ libjack2 ]}
+  '';
+
+  pythonImportsCheck = [ "jack" ];
+
+  # No unit tests; doctests require actual running JACK environment
+  doCheck = false;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "JACK Audio Connection Kit (JACK) Client for Python";
+    homepage = "https://jackclient-python.readthedocs.io/";
+    changelog = "https://jackclient-python.readthedocs.io/en/${version}/version-history.html";
+    license = with lib.licenses; [ mit ];
+    maintainers = with lib.maintainers; [ pluiedev ];
+  };
+}

pkgs/development/python-modules/pyalsa/default.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  alsa-lib,
+  nix-update-script,
+}:
+let
+  version = "1.2.12";
+in
+buildPythonPackage {
+  pname = "pyalsa";
+  inherit version;
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "alsa-project";
+    repo = "alsa-python";
+    tag = "v${version}";
+    hash = "sha256-a0hqYg4VE6L6PBPZW5aGPa5L16uI9eHGvoyZPMkqsMU=";
+  };
+
+  build-system = [ setuptools ];
+
+  buildInputs = [ alsa-lib ];
+
+  pythonImportsCheck = [ "pyalsa" ];
+
+  # Checks require a working ALSA environment
+  doCheck = false;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Python bindings for the Advanced Linux Sound Architecture (ALSA)";
+    homepage = "http://www.alsa-project.org";
+    license = with lib.licenses; [ lgpl2Plus ];
+    maintainers = with lib.maintainers; [ pluiedev ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -6491,6 +6491,8 @@ self: super: with self; {
 
   jaconv = callPackage ../development/python-modules/jaconv { };
 
+  jack-client = callPackage ../development/python-modules/jack-client { };
+
   jaeger-client = callPackage ../development/python-modules/jaeger-client { };
 
   jalali-core = callPackage ../development/python-modules/jalali-core { };
@@ -10425,6 +10427,8 @@ self: super: with self; {
 
   pyaehw4a1 = callPackage ../development/python-modules/pyaehw4a1 { };
 
+  pyalsa = callPackage ../development/python-modules/pyalsa { };
+
   pyalsaaudio = callPackage ../development/python-modules/pyalsaaudio { };
 
   pyatag = callPackage ../development/python-modules/pyatag { };