rofi-games: init at 1.10.2

pkgs/by-name/ro/rofi-games/fix-justfile.patch

@@ -0,0 +1,26 @@
+diff --git a/justfile b/justfile
+index cd111a1..b6f3827 100644
+--- a/justfile
++++ b/justfile
+@@ -13,9 +13,9 @@ PKGNAME := env("PKGNAME", "rofi-games")
+ PKGDIR := env("PKGDIR", "")
+ LIB_NAME := "librofi_games.so"
+ PLUGIN_NAME := "games.so"
+-THEMES_DIR := "/usr/share/rofi/themes"
+-LICENSES_DIR := "/usr/share/licenses/" + PKGNAME
+-PLUGINS_DIR := `pkg-config --variable pluginsdir rofi || if test -d "/usr/lib64"; then echo "/usr/lib64/rofi"; else echo "/usr/lib/rofi"; fi`
++THEMES_DIR := "/share/rofi/themes"
++LICENSES_DIR := "/share/licenses/" + PKGNAME
++PLUGINS_DIR := "/lib/rofi"
+ PLUGIN_PATH := join(PLUGINS_DIR, PLUGIN_NAME)
+
+ # Set rust flags if running a version of `rofi` with changes newer than the base `1.7.5`
+@@ -32,7 +32,7 @@ RUSTFLAGS := if `rofi -version` =~ '^Version: 1\.7\.5(?:\+wayland2)?$' { "" } el
+
+ # List commands
+ default:
+-    just --list
++    just build
+
+ # Build
+ build:

pkgs/by-name/ro/rofi-games/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  rustPlatform,
+  cargo,
+  just,
+  rofi,
+  pkg-config,
+  glib,
+  cairo,
+  pango,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rofi-games";
+  version = "1.10.2";
+
+  src = fetchFromGitHub {
+    owner = "Rolv-Apneseth";
+    repo = "rofi-games";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-4L3gk/RG9g5QnUW1AJkZIl0VkBiO/L0HUBC3pibN/qo=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-cU7gp/c1yx3ZLaZuGs1bvOV4AKgLusraILVJ2EhH1iA=";
+  };
+
+  patches = [
+    # fix the install locations of files and set default just task
+    ./fix-justfile.patch
+  ];
+
+  env.PKGDIR = placeholder "out";
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    rustPlatform.cargoSetupHook
+    cargo
+    just
+    rofi
+    pkg-config
+  ];
+
+  buildInputs = [
+    glib
+    cairo
+    pango
+  ];
+
+  meta = {
+    changelog = "https://github.com/Rolv-Apneseth/rofi-games/blob/${finalAttrs.src.rev}/CHANGELOG.md";
+    description = "Rofi plugin which adds a mode that will list available games for launch along with their box art";
+    homepage = "https://github.com/Rolv-Apneseth/rofi-games";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ tomasajt ];
+    platforms = lib.platforms.linux;
+  };
+})