shottr: init at 1.8.1

pkgs/by-name/sh/shottr/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  writeShellApplication,
+  cacert,
+  curl,
+  common-updater-scripts,
+  pup,
+  undmg,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "shottr";
+  version = "1.8.1";
+
+  src = fetchurl {
+    url = "https://shottr.cc/dl/Shottr-${finalAttrs.version}.dmg";
+    hash = "sha256-I3LNLuhIRdjKDn79HWRK2B/tVsV+1aGt/aY442y3r2I=";
+  };
+
+  nativeBuildInputs = [ undmg ];
+
+  sourceRoot = "Shottr.app";
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/Applications/Shottr.app"
+    cp -R . "$out/Applications/Shottr.app"
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = lib.getExe (writeShellApplication {
+    name = "shottr-update-script";
+    runtimeInputs = [
+      cacert
+      common-updater-scripts
+      curl
+      pup
+    ];
+    text = ''
+      version="$(curl -s https://shottr.cc/newversion.html \
+        | pup 'a[href*="Shottr-"] attr{href}' \
+        | sed -E 's|/dl/Shottr-||' \
+        | sed -E 's|\.dmg||')"
+      update-source-version shottr "$version"
+    '';
+  });
+
+  meta = {
+    changelog = "https://shottr.cc/newversion.html";
+    description = "MacOS screenshot app with scrolling screenshots, OCR, annotation and measurement instruments";
+    homepage = "https://shottr.cc/";
+    license = lib.licenses.unfree;
+    maintainers = with lib.maintainers; [ donteatoreo ];
+    platforms = lib.platforms.darwin;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+})