MUI - Auto select (activate) field

[Cvijo]

Hi all,

I have one form that is text input

MUIF_U8G2_U8_MIN_MAX("NV", &num_value, 0, 99, mui_u8g2_u8_min_max_wm_mud_pi),

and here is part of the form:

MUI_FORM(16)
MUI_STYLE(1)
MUI_LABEL(5, 8, "Postavljanje ON ")
MUI_XY("HR", 0,11)
MUI_STYLE(3)
MUI_XY("NV", 50, 40)
MUI_STYLE(0)

i want the form field "NV" to be auto-activated so that when i turn the rotary encoder it starts to go up/down .. now i need to press the encoder and then start to change it .. if it is only field on the form there is no need to sendSelect().

So when the user press the rotary button i would like to go to another form (exit)

Is that possible, i tried to find some examples but everything is using sendSelect()

[olikraus]

1. Use the MSE version of the input field: mui_u8g2_u8_min_max_wm_mse_pi
2. In the event handler use mui_SendValueIncrement(mui_t *ui) and mui_SendValueDecrement(mui_t *ui) instead of next/prev field functions for this form (this means, you might need to check for form 16 and then send different events to MUI).

Let me assume you took over the event handler from here:

u8g2/sys/arduino/u8g2_page_buffer/MUIInputSimpleRotary/MUIInputSimpleRotary.ino

Line 532 in 3e68b43

void handle_events(void) {

Then the new event handler may look like this:

void handle_events(void) {
  // 0 = not pushed, 1 = pushed  
  if ( push_event == 1 ) {
      mui.sendSelect();
      is_redraw = 1;
      push_event = 0;
  }

 if ( mui.getCurrentFormId() == 16 ) {
    // 0 = not turning, 1 = CW, 2 = CCW
    if ( rotary_event == 1 ) {
      mui_SendValueIncrement(mui.getMUI());
      is_redraw = 1;
      rotary_event = 0;
    }
    if ( rotary_event == 2 ) {
      mui_SendValueDecrement(mui.getMUI());
      is_redraw = 1;
      rotary_event = 0;
    }    
 }
 else {  
    // 0 = not turning, 1 = CW, 2 = CCW
    if ( rotary_event == 1 ) {
      mui.nextField();
      is_redraw = 1;
      rotary_event = 0;
    }
    if ( rotary_event == 2 ) {
      mui.prevField();
      is_redraw = 1;
      rotary_event = 0;
    }    
  }
}

... not tested...

[olikraus]

Another idea: You could do the mapping of the events inside a custom MUIF:

uint8_t my_mui_u8g2_u8_min_max_wm_mse_pi(mui_t *ui, uint8_t msg)
{
  if ( msg == MUIF_MSG_EVENT_NEXT)
    return mui_u8g2_u8_min_max_wm_mse_pi(ui, MUIF_MSG_VALUE_INCREMENT);
  if ( msg == MUIF_MSG_EVENT_PREV)
    return mui_u8g2_u8_min_max_wm_mse_pi(ui, MUIF_MSG_VALUE_DECREMENT);
  return mui_u8g2_u8_min_max_wm_mse_pi(ui, msg);
}

Then just use this extended MUIF:

MUIF_U8G2_U8_MIN_MAX("NV", &num_value, 0, 99, my_mui_u8g2_u8_min_max_wm_mse_pi),

Again, not tested, but it looks little bit cleaner to me.

[Cvijo]

Ty @olikraus, i didn't know that "mse" version would auto-activate a field. The second version you gave looks much nicer and cleaner (not to mess with handle_events) and i will try it next week when i get back.

I was struggling with push the button to activate "back" command, i tried to use "MUIF_MSG_CURSOR_LEAVE" to call mui.gotoForm .. but the problem is every turn of rotary it is fired too (ENTER and LEAVE ), you have any idea how to get that functionality.