From 406fb00b1759fc9948fc7937839f4ab8ffdce1f6 Mon Sep 17 00:00:00 2001
From: Hoang Nguyen <folliekazetani@protonmail.com>
Date: Sat, 4 Jan 2025 00:00:00 +0700
Subject: [PATCH] earthly: init module

Earthly is a build configuration framework utilizing buildkit and
Dockerfile-like syntax for simplicity and fast builds.
---
 modules/lib/maintainers.nix                   |  6 +++
 modules/misc/news.nix                         | 10 +++++
 modules/modules.nix                           |  1 +
 modules/programs/earthly.nix                  | 42 +++++++++++++++++++
 tests/default.nix                             |  1 +
 tests/modules/programs/earthly/default.nix    |  1 +
 .../programs/earthly/earthly-settings.nix     | 21 ++++++++++
 .../programs/earthly/earthly-settings.yml     |  6 +++
 8 files changed, 88 insertions(+)
 create mode 100644 modules/programs/earthly.nix
 create mode 100644 tests/modules/programs/earthly/default.nix
 create mode 100644 tests/modules/programs/earthly/earthly-settings.nix
 create mode 100644 tests/modules/programs/earthly/earthly-settings.yml

diff --git a/modules/lib/maintainers.nix b/modules/lib/maintainers.nix
index 7ee9e1df9c1b..03e5009a16a9 100644
--- a/modules/lib/maintainers.nix
+++ b/modules/lib/maintainers.nix
@@ -628,4 +628,10 @@
     github = "ALameLlama";
     githubId = 55490546;
   };
+  folliehiyuki = {
+    name = "Hoang Nguyen";
+    email = "folliekazetani@protonmail.com";
+    github = "folliehiyuki";
+    githubId = 67634026;
+  };
 }
diff --git a/modules/misc/news.nix b/modules/misc/news.nix
index 699398dee44a..c821559050ae 100644
--- a/modules/misc/news.nix
+++ b/modules/misc/news.nix
@@ -1947,6 +1947,16 @@ in {
           speed, features, or native UIs. Ghostty provides all three.
         '';
       }
+
+      {
+        time = "2025-01-04T16:53:20+00:00";
+        message = ''
+          A new module is available: 'programs.earthly'.
+
+          Earthly is a build configuration framework utilizing buildkit and
+          Dockerfile-like syntax for fast builds and simplicity.
+        '';
+      }
     ];
   };
 }
diff --git a/modules/modules.nix b/modules/modules.nix
index 3c422eb5ed97..8029fdb3604d 100644
--- a/modules/modules.nix
+++ b/modules/modules.nix
@@ -86,6 +86,7 @@ let
     ./programs/dircolors.nix
     ./programs/direnv.nix
     ./programs/discocss.nix
+    ./programs/earthly.nix
     ./programs/eclipse.nix
     ./programs/emacs.nix
     ./programs/eww.nix
diff --git a/modules/programs/earthly.nix b/modules/programs/earthly.nix
new file mode 100644
index 000000000000..4458593e1f42
--- /dev/null
+++ b/modules/programs/earthly.nix
@@ -0,0 +1,42 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.earthly;
+
+  yamlFormat = pkgs.formats.yaml { };
+
+in {
+  meta.maintainers = [ maintainers.folliehiyuki ];
+
+  options.programs.earthly = {
+    enable = mkEnableOption "earthly";
+
+    package = mkPackageOption pkgs "earthly" { };
+
+    settings = mkOption {
+      type = yamlFormat.type;
+      default = { };
+      description = ''
+        Configuration written to ~/.earthly/config.yml file.
+        See https://docs.earthly.dev/docs/earthly-config for supported values.
+      '';
+      example = literalExpression ''
+        global = {
+          disable_analytics = true;
+          disable_log_sharing = true;
+        };
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+
+    home.file.".earthly/config.yml" = mkIf (cfg.settings != { }) {
+      source = yamlFormat.generate "earthly-config" cfg.settings;
+    };
+  };
+}
diff --git a/tests/default.nix b/tests/default.nix
index 3530138da0ef..15d820a36c83 100644
--- a/tests/default.nix
+++ b/tests/default.nix
@@ -72,6 +72,7 @@ in import nmtSrc {
     ./modules/programs/darcs
     ./modules/programs/dircolors
     ./modules/programs/direnv
+    ./modules/programs/earthly
     ./modules/programs/emacs
     ./modules/programs/fastfetch
     ./modules/programs/feh
diff --git a/tests/modules/programs/earthly/default.nix b/tests/modules/programs/earthly/default.nix
new file mode 100644
index 000000000000..5606289c177e
--- /dev/null
+++ b/tests/modules/programs/earthly/default.nix
@@ -0,0 +1 @@
+{ earthly-settings = ./earthly-settings.nix; }
diff --git a/tests/modules/programs/earthly/earthly-settings.nix b/tests/modules/programs/earthly/earthly-settings.nix
new file mode 100644
index 000000000000..a5115a9ec096
--- /dev/null
+++ b/tests/modules/programs/earthly/earthly-settings.nix
@@ -0,0 +1,21 @@
+_:
+
+{
+  programs.earthly = {
+    enable = true;
+
+    settings = {
+      global.disable_analytics = true;
+
+      git."github.com" = {
+        auth = "ssh";
+        user = "username";
+      };
+    };
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.earthly/config.yml
+    assertFileContent home-files/.earthly/config.yml ${./earthly-settings.yml}
+  '';
+}
diff --git a/tests/modules/programs/earthly/earthly-settings.yml b/tests/modules/programs/earthly/earthly-settings.yml
new file mode 100644
index 000000000000..182f011b2975
--- /dev/null
+++ b/tests/modules/programs/earthly/earthly-settings.yml
@@ -0,0 +1,6 @@
+git:
+  github.com:
+    auth: ssh
+    user: username
+global:
+  disable_analytics: true