build.gradle

plugins {
    id 'groovy'
    id 'java-library'
    id 'io.github.gradle-nexus.publish-plugin'
    id 'maven-publish'
    id 'signing'
}

version =  projectVersion
group = 'org.grails.plugins'
ext.set('grailsVersion', libs.versions.grails.get())
ext.set('isReleaseVersion', !version.toString().endsWith('-SNAPSHOT'))
ext.set('isSnapshot', !isReleaseVersion)

apply plugin: 'org.grails.grails-plugin' // Needs to be applied after grailsVersion has been set

repositories {
  mavenLocal()
  mavenCentral()
  maven { url = 'https://repo.grails.org/grails/core' }
}

dependencies {

    api libs.quartz

    implementation libs.grails.bootstrap
    implementation libs.grails.core
    implementation libs.groovy.sql
    implementation libs.spring.beans
    implementation libs.spring.context
    implementation libs.spring.context.support

    compileOnly libs.groovy.core // CompileStatic and Slf4j
    compileOnly libs.javax.annotation.api // Provided

    testImplementation libs.spock.core

    testRuntimeOnly libs.slf4j.nop // Get rid of warning about missing slf4j implementation during test task
}

apply from: layout.projectDirectory.file('gradle/java-config.gradle')
apply from: layout.projectDirectory.file('gradle/grails-plugin-config.gradle')
apply from: layout.projectDirectory.file('gradle/testing-config.gradle')
apply from: layout.projectDirectory.file('gradle/documentation-config.gradle')
apply from: layout.projectDirectory.file('gradle/publishing.gradle')