build.gradle

plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.gradle.userdev' version '7.0.57' // Cannot be .70 or past (for now)
    id 'net.neoforged.gradle.mixin' version '7.0.57'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'antlr'
}

version = mod_version
group = mod_group_id

configurations {
    shade
}

shadowJar {
    archiveClassifier.set('')
    configurations = [project.configurations.shade]
    // Ugly relocating, not arsed to find a better way
    // This won't be published on the mod websites anyway
    relocate 'com.google', 'worldedit.com.google'
    relocate 'org.apache', 'worldedit.org.apache'
    relocate 'org.checkerframework', 'worldedit.org.checkerframework'
    relocate 'javax.annotation', 'worldedit.javax.annotation'
}

repositories {
    mavenLocal()

    maven {
        name 'EngineHub Repository'
        url 'https://maven.enginehub.org/repo/'
    }
}

base {
    archivesName = mod_id
}

mixin {
    //add(sourceSets.main, "worldedit-neoforge.refmap.json") // Neoforge doesn't need refmapping
    config "worldedit-neoforge.mixins.json"
}

// Mojang ships Java 17 to end users in 1.18+, so your mod should target Java 17.
java.toolchain.languageVersion = JavaLanguageVersion.of(17)

minecraft.accessTransformers.file rootProject.file('src/main/resources/META-INF/accesstransformer.cfg')
//minecraft.accessTransformers.entry public net.minecraft.client.Minecraft textureManager # textureManager

// Default run configurations.
// These can be tweaked, removed, or duplicated as needed.
runs {
    // applies to all the run configs below
    configureEach {
        dependencies { // Requires neogradle version lesser than .70 (for now)
            runtime "net.kyori:text-api:${TEXT}"
            runtime "net.kyori:text-serializer-gson:${TEXT}"
            runtime "net.kyori:text-serializer-legacy:${TEXT}"
            runtime "net.kyori:text-serializer-plain:${TEXT}"

            runtime "org.enginehub.piston:core:${PISTON}"
            runtime "org.enginehub.piston.core-ap:runtime:${PISTON}"
            runtime "org.enginehub.piston:default-impl:${PISTON}"
        }

        // Recommended logging data for a userdev environment
        // The markers can be added/remove as needed separated by commas.
        // "SCAN": For mods scan.
        // "REGISTRIES": For firing of registry events.
        // "REGISTRYDUMP": For getting the contents of all registries.
        systemProperty 'forge.logging.markers', 'REGISTRIES'

        // Recommended logging level for the console
        // You can set various levels here.
        // Please read: https://stackoverflow.com/questions/2031163/when-to-use-the-different-log-levels
        systemProperty 'forge.logging.console.level', 'debug'

        modSource project.sourceSets.main
    }

    client {
        // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
        systemProperty 'forge.enabledGameTestNamespaces', project.mod_id
    }

    server {
        systemProperty 'forge.enabledGameTestNamespaces', project.mod_id
        programArgument '--nogui'
    }

    // This run config launches GameTestServer and runs all registered gametests, then exits.
    // By default, the server will crash when no gametests are provided.
    // The gametest system is also enabled by default for other run configs under the /test command.
    gameTestServer {
        systemProperty 'forge.enabledGameTestNamespaces', project.mod_id
    }

    data {
        // example of overriding the workingDirectory set in configureEach above, uncomment if you want to use it
        // workingDirectory project.file('run-data')

        // Specify the modid for data generation, where to output the resulting resource, and where to look for existing resources.
        programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
    }
}

// Include resources generated by data generators.
sourceSets.main.resources { srcDir 'src/generated/resources' }

dependencies {
    // Specify the version of Minecraft to use.
    // Depending on the plugin applied there are several options. We will assume you applied the userdev plugin as shown above.
    // The group for userdev is net.neoforged, the module name is neoforge, and the version is the same as the neoforge version.
    // You can however also use the vanilla plugin (net.neoforged.gradle.vanilla) to use a version of Minecraft without the neoforge loader.
    // And its provides the option to then use net.minecraft as the group, and one of; client, server or joined as the module name, plus the game version as version.
    // For all intends and purposes: You can treat this dependency as if it is a normal library you would use.
    implementation "net.neoforged:neoforge:${neo_version}"

    implementation "net.kyori:text-api:${TEXT}"
    implementation "net.kyori:text-serializer-gson:${TEXT}"
    implementation "net.kyori:text-serializer-legacy:${TEXT}"
    implementation "net.kyori:text-serializer-plain:${TEXT}"
    implementation "org.enginehub.piston:core:${PISTON}"
    implementation "org.enginehub.piston.core-ap:runtime:${PISTON}"
    implementation "org.enginehub.piston:default-impl:${PISTON}"

    shade "net.kyori:text-api:${TEXT}"
    shade "net.kyori:text-serializer-gson:${TEXT}"
    shade "net.kyori:text-serializer-legacy:${TEXT}"
    shade "net.kyori:text-serializer-plain:${TEXT}"
    shade "org.enginehub.piston:core:${PISTON}"
    shade "org.enginehub.piston.core-ap:runtime:${PISTON}"
    shade "org.enginehub.piston:default-impl:${PISTON}"

    implementation "com.sk89q.lib:jlibnoise:1.0.0"
    implementation "org.yaml:snakeyaml:2.0"
    implementation "org.enginehub.piston.core-ap:annotations:${PISTON}"
    implementation "org.enginehub.piston.core-ap:processor:${PISTON}"
    annotationProcessor "org.enginehub.piston.core-ap:annotations:${PISTON}"
    annotationProcessor "org.enginehub.piston.core-ap:processor:${PISTON}"
    implementation ("com.sk89q:jchronic:0.2.4a") {
        exclude group: "junit", module: "junit"
    }
    implementation("com.google.auto.value:auto-value-annotations:${AUTO_VALUE}")
    annotationProcessor("com.google.auto.value:auto-value:${AUTO_VALUE}")
    antlr("org.antlr:antlr4:4.9.1")
    implementation("org.antlr:antlr4-runtime:4.9.1")
    implementation("de.schlichtherle:truezip:6.8.4")
    implementation("org.mozilla:rhino-runtime:1.7.13")

    // Example mod dependency with JEI
    // The JEI API is declared for compile time use, while the full JEI artifact is used at runtime
    // compileOnly "mezz.jei:jei-${mc_version}-common-api:${jei_version}"
    // compileOnly "mezz.jei:jei-${mc_version}-forge-api:${jei_version}"
    // runtimeOnly "mezz.jei:jei-${mc_version}-forge:${jei_version}"

    // Example mod dependency using a mod jar from ./libs with a flat dir repository
    // This maps to ./libs/coolmod-${mc_version}-${coolmod_version}.jar
    // The group id is ignored when searching -- in this case, it is "blank"
    // implementation "blank:coolmod-${mc_version}:${coolmod_version}"

    // Example mod dependency using a file as dependency
    // implementation files("libs/coolmod-${mc_version}-${coolmod_version}.jar")

    // Example project dependency using a sister or child project:
    // implementation project(":myproject")

    // For more info:
    // http://www.gradle.org/docs/current/userguide/artifact_dependencies_tutorial.html
    // http://www.gradle.org/docs/current/userguide/dependency_management.html
}

// This block of code expands all declared replace properties in the specified resource targets.
// A missing property will result in an error. Properties are expanded using ${} Groovy notation.
// When "copyIdeResources" is enabled, this will also run before the game launches in IDE environments.
// See https://docs.gradle.org/current/dsl/org.gradle.language.jvm.tasks.ProcessResources.html
tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            minecraft_version   : minecraft_version, minecraft_version_range: minecraft_version_range,
            neo_version         : neo_version, neo_version_range: neo_version_range,
            loader_version_range: loader_version_range,
            mod_id              : mod_id, mod_name: mod_name, mod_license: mod_license, mod_version: mod_version,
            mod_authors         : mod_authors, mod_description: mod_description, pack_format_number: pack_format_number,
    ]
    inputs.properties replaceProperties

    filesMatching(['META-INF/mods.toml', 'pack.mcmeta']) {
        expand replaceProperties + [project: project]
    }
}

tasks.named('generateGrammarSource', AntlrTask) {
    def pkg = 'com.sk89q.worldedit.antlr'
    outputDirectory = file("build/generated-src/antlr/main/${pkg.replace('.', '/')}")
    arguments = [
            '-visitor', '-package', pkg,
            '-Xexact-output-dir'
    ]
}

def altConfigFiles = { String artifactType ->
    def deps = configurations.shade.incoming.dependencies.findAll { it instanceof ModuleDependency }
            .collect { dependency ->
                def depCopy = dependency.copy()
                depCopy.artifact {
                    name = dependency.name
                    type = artifactType
                    extension = 'jar'
                    classifier = artifactType
                }
                depCopy
            }

    files(configurations.detachedConfiguration(deps.toArray(new Dependency[0]))
            .resolvedConfiguration.lenientConfiguration.artifacts.findAll { it.classifier == artifactType }
            .collect { zipTree(it.file) })
}

tasks.register('sourcesJar', Jar) {
    from {
        altConfigFiles('sources')
    }
    archiveClassifier = 'sources'
}

tasks.named('sourcesJar') {
    mustRunAfter 'generateGrammarSource'
}

plugins.withId('idea') {
    idea {
        module {
            sourceDirs += files('src/main/antlr')
            sourceDirs += files('build/generated-src/antlr/main')
            generatedSourceDirs += files('build/generated-src/antlr/main')
        }
    }
}


// Example configuration to allow publishing using the maven-publish plugin
publishing {
    publications {
        register('mavenJava', MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            url "file://${project.projectDir}/repo"
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

build.dependsOn shadowJar