From 928bb2351da985d4fe912f77e3ad2eee8846087e Mon Sep 17 00:00:00 2001
From: Leah Amelia Chen <hi@pluie.me>
Date: Fri, 6 Dec 2024 00:10:08 +0100
Subject: [PATCH] linux-show-player: init at 0.6.4

---
 pkgs/by-name/li/linux-show-player/package.nix | 85 +++++++++++++++++++
 1 file changed, 85 insertions(+)
 create mode 100644 pkgs/by-name/li/linux-show-player/package.nix

diff --git a/pkgs/by-name/li/linux-show-player/package.nix b/pkgs/by-name/li/linux-show-player/package.nix
new file mode 100644
index 00000000000000..1645811e68000b
--- /dev/null
+++ b/pkgs/by-name/li/linux-show-player/package.nix
@@ -0,0 +1,85 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+  qt5,
+  wrapGAppsHook3,
+  gobject-introspection,
+  libjack2,
+  ola,
+  nix-update-script,
+}:
+let
+  version = "0.6.4";
+in
+python3.pkgs.buildPythonApplication {
+  pname = "linux-show-player";
+  inherit version;
+  pyproject = true;
+
+  # 3.13 is unsupported for now
+  disabled = with python3.pkgs; pythonOlder "3.8" || pythonAtLeast "3.13";
+
+  src = fetchFromGitHub {
+    owner = "FrancescoCeruti";
+    repo = "linux-show-player";
+    tag = "v${version}";
+    hash = "sha256-HDL3oL2N3nneXs37N/UPil8RwN1pC0sU23xVtGfOrb0=";
+  };
+
+  nativeBuildInputs = [
+    qt5.wrapQtAppsHook
+    wrapGAppsHook3
+
+    gobject-introspection
+  ];
+
+  build-system = with python3.pkgs; [ poetry-core ];
+
+  dependencies = with python3.pkgs; [
+    appdirs
+    falcon
+    jack-client
+    mido
+    pygobject3
+    pyqt5
+    python-rtmidi
+    requests
+    sortedcontainers
+    humanize
+    pyalsa
+    pyliblo
+
+    # Undocumented dependencies. *sigh*
+    gst-python
+    ola # Using Python bindings
+  ];
+
+  buildInputs = [ libjack2 ];
+
+  pythonRemoveDeps = [
+    "pyqt5-qt5"
+    "pyliblo3"
+  ];
+
+  dontWrapQtApps = true;
+  dontWrapGApps = true;
+
+  makeWrapperArgs = [
+    ''--prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ libjack2 ]}"''
+    "\${qtWrapperArgs[@]}"
+    "\${gappsWrapperArgs[@]}"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Cue player designed for stage productions";
+    changelog = "https://github.com/FrancescoCeruti/linux-show-player/releases/tag/v${version}";
+    homepage = "https://linux-show-player.org/";
+    license = with lib.licenses; [ gpl3Only ];
+    maintainers = with lib.maintainers; [ pluiedev ];
+    platforms = lib.platforms.linux;
+    mainProgram = "linux-show-player";
+  };
+}